mirror of
https://github.com/jesseduffield/lazygit.git
synced 2026-09-10 07:36:27 -04:00
658a66e14b
`just e2e` was the visible-UI runner, but it's only useful for a single test (and even then only with --sandbox/--slow); running it without arguments is far too slow, yet it was easy to invoke by reflex when `just e2e-all` (run all headlessly) was meant. Make `just e2e` the everyday headless runner: no arguments runs the whole suite (what e2e-all did), and a test name runs just that one headlessly via `go test -run` — which we had no target for before. The visible-UI runner moves to `e2e-cli`, pairing with the existing `e2e-tui` (the two main.go subcommands). e2e-all is now redundant and removed. Co-Authored-By: Claude Opus 4.8 (1M context) <noreply@anthropic.com>
78 lines
1.9 KiB
Makefile
78 lines
1.9 KiB
Makefile
default:
|
|
just --list
|
|
|
|
# Build lazygit with optimizations disabled (to make debugging easier).
|
|
build:
|
|
go build -gcflags='all=-N -l'
|
|
|
|
install:
|
|
go install
|
|
|
|
run: build
|
|
./lazygit
|
|
|
|
# Run `just debug` in one terminal tab and `just print-log` in another to view the program and its log output side by side
|
|
debug: build
|
|
./lazygit -debug
|
|
|
|
print-log: build
|
|
./lazygit --logs
|
|
|
|
unit-test:
|
|
go test ./... -short
|
|
|
|
# Run both unit tests and integration tests.
|
|
[unix]
|
|
test: unit-test e2e
|
|
|
|
# On Windows, integration tests are not supported right now
|
|
[windows]
|
|
test: unit-test
|
|
|
|
# Generate all our auto-generated files (test list, cheatsheets, json schema, maybe other things in the future)
|
|
generate:
|
|
go generate ./...
|
|
|
|
format:
|
|
gofumpt -l -w .
|
|
|
|
lint:
|
|
./scripts/golangci-lint-shim.sh run
|
|
|
|
e2e-test-command := "go test pkg/integration/clients/*.go"
|
|
|
|
# Run integration tests headlessly: no args runs all tests, a test name (or path) runs just that one. Use e2e-cli for a visible UI.
|
|
e2e *args:
|
|
{{ if args == "" { e2e-test-command } else { \
|
|
e2e-test-command + " -run 'TestIntegration/" + \
|
|
replace( \
|
|
replace_regex( \
|
|
replace_regex(args, '\S*pkg/integration/tests/', ''), \
|
|
'\.go( |$)', '${1}' \
|
|
), \
|
|
" ", "$' && " + e2e-test-command + " -run 'TestIntegration/" \
|
|
) + "$'" \
|
|
} }}
|
|
|
|
# Run a single integration test with a visible UI; most useful with --sandbox or --slow.
|
|
e2e-cli *args:
|
|
go run cmd/integration_test/main.go cli {{ args }}
|
|
|
|
# Open the TUI for running integration tests.
|
|
e2e-tui *args:
|
|
go run cmd/integration_test/main.go tui {{ args }}
|
|
|
|
# Run some tests on the current commit, similar to what CI does.
|
|
check:
|
|
./scripts/check_commit.sh
|
|
|
|
bump-gocui:
|
|
scripts/bump_gocui.sh
|
|
|
|
# Record a demo
|
|
demo *args:
|
|
demo/record_demo.sh {{ args }}
|
|
|
|
vendor:
|
|
go mod vendor && go mod tidy
|